電子工作編

基本構造

Arduino 系のプログラムは、最初に 1 回だけ実行される setup() と、その後くり返し実行される loop() を基本にして構成します。setup()の前に定義を書きます。ここら辺は使いながら慣れてください（規則はいくらでもありますから、説明していくときりがないです）。 このコードを実際にコピペするのでなくて、手入力して書き込んでみてください。もちろんコメントアウトは書かなくていいですが、コメントアウトは適宜使用してみてください。

#include <Arduino.h> // ここにライブラリを追加

const int ledPin = 8; //ピンの定義　GPIOで記述する場合はD8とする。これはケースバイケース

void setup() {//setup関数は最初に1回だけ実行される関数。void型であることには注意。voidの説明は後にします。
  pinMode(ledPin, OUTPUT); //ピンのモードを出力に設定
}

void loop() {//繰り返し実行される関数
  digitalWrite(ledPin, HIGH); //LEDを点灯
  delay(1000); //1秒待つ
  digitalWrite(ledPin, LOW); //LEDを消灯
  delay(1000); //1秒待つ
}

変数、関数、制御文の変更

基本構造を書けるようになったら、次は値の変更、関数の追加、条件分岐の利用を試します。少しずつ変更して、どの記述がどの動作に対応しているかを見ていくのが大事です。 ここら辺は、書いて真似て制御文の意味を考えていく、体裁的なことというより、慣れるセクションです。 以下のサンプルコードを真似して自らの手で書いて変化を見てください。 そして、そのコードをteamsで共有してください。 ここら辺からエラーが発生しやすくなります。気軽にセンパイに聞いてみてください。

サンプルコード1

#include <Arduino.h> // ここにライブラリを追加

const int ledPin = 8; //ピンの定義　GPIOで記述する場合はD8とする。これはケースバイケース

void setup() {
}

void loop() {
  for(int i = 0; i < 6; i++) { //漸かにLEDの明るさを変えるループ
    analogWrite(ledPin, 50*i); //LEDを点灯
    delay(500); //500ミリ秒待つ
  }
}

サンプルコード2

関数を分けて、点滅と明るさの変化を切り替えて動かすサンプルコードです。関数の作り方、使い方はあとで説明します。

#include <Arduino.h>//ここにライブラリを追加

const int ledPin = 8; //ピンの定義　GPIOで記述する場合はD8とする。これはケースバイケース

void blink(){
  analogWrite(ledPin, 255); //LEDを点灯
  delay(1000); //1000ミリ秒待つ
  analogWrite(ledPin, 0); //LEDを消灯
  delay(1000); //1000ミリ秒待つ
}

void illumination(){
  for (int i =0; i < 10; i++){
    analogWrite(ledPin, i*25); //LEDの明るさを変える
    delay(100); //100ミリ秒待つ
  }
  for (int i =9; i >= 0; i--){
    analogWrite(ledPin, i*25); //LEDの明るさを変える
    delay(100); //100ミリ秒待つ
  }
}

void setup() {
  //私はここにpinMode(ledPin, OUTPUT); //LEDピンを出力に設定するコードを入れたところ光りませんでした。
  //pinModeを設定後にanalog出力にしたため、digitalWriteで点灯させることができませんでした。
  blink(); //点滅関数を呼び出す
  illumination(); //明るさ変化関数を呼び出す
}

void loop() {//関数を使って記述した場合。同じような処理の場合、関数を使うことでloop文の中を減らせる
  blink();
  illumination();
  blink();
  blink();
  illumination();
}

サンプルコード3

ここに2つ目のコードについての説明を書いてください。

// ここに2つ目のコードを書いてください
void setup() {
}

void loop() {
}

ここに3つ目のコードについての説明を書いてください。

// ここに3つ目のコードを書いてください
void setup() {
}

        void loop() {
}

i2c通信とOLEDのキャラクタデバイスについて

続いてはシリアル通信の一つI2C(アイスクエアド通信）通信とOLEDのキャラクタデバイスについてです。I2Cの最大の特徴は、少ない本数の配線で複数のデバイスと通信できる点です。 SDA（データを送る線） と SCL（クロックを送る線） の 2 本を主に使います。 マスター（親）とスレーブ（子）の関係で通信を行い、マスターがスレーブに対してアドレスを指定して通信します。 これにより、複数のデバイスを同じ線でつなげることができます。 詳しくは、こちらを見てください。

今回は、OLEDを用いて、I2C通信はどういったもので、どうコーディングするべきかを体験して頂きます。 そのため、多くのライブラリを用いますが、ライブラリの内容についてはあまり深く説明しません（説明しても意味ないから）。 とりあえず、コードを真似して動かしてみてください。尚、シリアル通信を見る方法は、資料を参照ください。

サンプルコード

#include  //ここにライブラリを追加
#include  //I2C通信ライブラリ
#include  //OLEDディスプレイライブラリ
#include  //グラフィックライブラリ

#define SCREEN_WIDTH 128 // OLEDの表示幅, ピクセル単位
#define SCREEN_HEIGHT 64 // OLEDの表示高さ, ピクセル単位
#define OLED_RESET -1 // OLEDリセットピン（使用しない場合は-1）
#define SCREEN_ADDRESS 0x3C // よく使われるSSD1306のI2Cアドレス

Adafruit_SSD1306 display(SCREEN_WIDTH, SCREEN_HEIGHT, &Wire, OLED_RESET);

void setup() {
  Serial.begin(115200);//シリアル通信の初期化。通信速度は115200bpsに設定
  Wire.begin();// I2C通信の初期化

  if (!display.begin(SSD1306_SWITCHCAPVCC, SCREEN_ADDRESS)) {//3.3V電源を使用する場合はSSD1306_SWITCHCAPVCCを指定し、よく使われるI2Cアドレス0x3Cを指定してOLEDを初期化
    while (true) {
      Serial.println("OLED init failed");// OLEDの初期化に失敗した場合はシリアルモニタにエラーメッセージを表示
      delay(100);
    }
  }// OLEDの初期化に失敗した場合はここで止まる

  display.clearDisplay();// OLEDの画面をクリア　これがないと前の表示が残ることがある。　これはOLED側のマイコンのメモリに前の表示が残っているためで、OLEDを初期化した後は必ず画面をクリアすることが推奨される
  display.setTextSize(1);// テキストサイズを1に設定（デフォルトは1）
  display.setTextColor(SSD1306_WHITE);// テキストカラーを白に設定
  display.setCursor(0, 0);// テキストの表示位置を左上に設定
  display.println("welcome to R-sec");//ln()は改行を行う関数。これで文字列を表示した後に次の行に移る 次の文から改行が始まる
  display.println("Hello, World!");// 文字列を表示
  display.display();
}

void loop() {
  delay(1000);
}

次は、OLED上に任意の文字以外の要素を表示する方法についてです。 これは、以外にもシンプルであり、I2C通信にはあまり関係ないため、あまり深く説明しません。 これこそ、AIの出番です。「SSD1306にかわいい顔を表示するサンプルコードを書いて」等と 入力してみてください。

シリアル通信

次はシリアル通信です。シリアル通信を使うと、マイコンの中で何が起きているかをパソコン側へ文字として送れます。 センサの値を確認したり、どこまで処理が進んだかを調べたりするときにとても便利です。 最初のうちは LED の点滅だけでなく、Serial.print() や Serial.println() を使って状態を表示する練習をしておくと、デバッグがかなりやりやすくなります。 デバックとは、プログラムの動作を追跡し、問題を特定するための手法です。思った動きをしないとき、どこが原因なのか発見するのに役立ちます。 実は、void setup(){}でSerial.begin(speed)と入力しその後Serial.print(letter or number) と入力するだけです。これを使って今のエラーコードが出るコードを修正してください。これに関しては、コピペで行って構いません。シリアル通信については、資料を参照ください。

サンプルコード

#include 
const int led = 8;
int state = LOW;

void setup() {
  Serial.begin(9600);
  pinMode(led, OUTPUT);
}

void loop() {
  state == !state;

  //Serial.println(state);

  digitalWrite(led, state);
  delay(500);
}

このコードでは、0.5秒ごとに state の値をシリアルモニタへ送っています。PlatformIO ならシリアルモニタを開いて確認でき、Arduino IDE でも同じように表示を見られます。 このコードだと、ledが光りません。問題はloop関数内にあります。

RCカーの作成

最後のステップです。BLE通信を使ってRCカーを操作します。BLEとは Bluetooth Low Energy の略で、低消費電力で短距離の通信ができる技術です。 Wi-fiやBluettoth Classicと比べて、消費電力が少ないため、バッテリー駆動のデバイスでよく使われます。 ただ、BLEは常時通信をしないことで、省電力を実現しているため、通信のタイミングや方法が少し特殊です。 ここでは、BLE通信の基本的な流れと、RCカーの操作に必要なコードの例を紹介します。 このセクションは、実装を目的としますので、コードの深い理解は必要としません。 とりあえず、コードを真似して動かしてみてください。 尚、リモコンは、Pythonで書いています。pythonのＰＣへの導入方法は、資料を参照ください。

ESP32 (XIAO) 側サンプルコード

#include <Arduino.h>
#include <BLEDevice.h>
#include <BLEServer.h>
#include <BLEUtils.h>
#include <BLE2902.h>

//必ずGPIO指定。何故かこうしないとクラッシュする
const int motorR_Pin1 = D2;// GPIO2
const int motorR_Pin2 = D1;// GPIO1
const int motorL_Pin1 = D3;// GPIO3
const int motorL_Pin2 = D10;// GPIO10
const int motorR_PWM = D0;// GPIO0
const int motorL_PWM = D6;// GPIO6

// Nordic UART Service (NUS) UUID — controller.py と同じ
#define SERVICE_UUID "6E400001-B5A3-F393-E0A9-E50E24DCCA9E"  // サービスUUID (NUS) 重複してはならないため要設定がいる
#define RX_UUID      "6E400002-B5A3-F393-E0A9-E50E24DCCA9E"  // Python → ESP32
#define TX_UUID      "6E400003-B5A3-F393-E0A9-E50E24DCCA9E"  // ESP32 → Python

BLECharacteristic* pTxCharacteristic = nullptr;// BLE通知用グローバル変数

// モーター制御
int gSpeed = 153;       // 現在の速度 (0-255)、デフォルト153
String gCmd  = "STOP";  // 現在実行中のコマンド

// モーター制御関数。speedの正負で回転方向を制御し、絶対値で速度を制御します。
void setMotor(int pin1, int pin2, int pwmPin, int speed) {
  if (speed > 0) {
    digitalWrite(pin1, HIGH);
    digitalWrite(pin2, LOW);
  } else if (speed < 0) {
    digitalWrite(pin1, LOW);
    digitalWrite(pin2, HIGH);
  } else {
    digitalWrite(pin1, LOW);
    digitalWrite(pin2, LOW);
  }
  analogWrite(pwmPin, abs(speed));
}

// 左右のモーターを同時に制御する関数
void driveMotors(int left, int right) {
  setMotor(motorL_Pin1, motorL_Pin2, motorL_PWM, left);
  setMotor(motorR_Pin1, motorR_Pin2, motorR_PWM, right);
}

// 現在の gCmd を gSpeed で再適用する（速度変更時に即時反映）
void applyCmd() {
  if      (gCmd == "FORWARD") driveMotors( gSpeed,  gSpeed);
  else if (gCmd == "BACK")    driveMotors(-gSpeed, -gSpeed);
  else if (gCmd == "LEFT")    driveMotors(-gSpeed,  gSpeed);
  else if (gCmd == "RIGHT")   driveMotors( gSpeed, -gSpeed);
  else                        driveMotors(0, 0);
}

// Python へ文字列を通知送信
void sendNotify(const char* msg) {
  if (pTxCharacteristic == nullptr) return;
  pTxCharacteristic->setValue((uint8_t*)msg, strlen(msg));
  pTxCharacteristic->notify();
}

// BLE書き込みコールバック (Python → ESP32)
// コマンド例: "FORWARD", "BACK", "LEFT", "RIGHT", "STOP"
class RxCallbacks : public BLECharacteristicCallbacks {
  void onWrite(BLECharacteristic* pCharacteristic) override {
    std::string raw = pCharacteristic->getValue();
    if (raw.empty()) return;

    // 末尾の改行・スペースを除去
    while (!raw.empty() && (raw.back() == '\n' || raw.back() == '\r' || raw.back() == ' ')) {
      raw.pop_back();
    }

    String cmd = String(raw.c_str());
    cmd.trim();
    Serial.printf("BLE command: %s\n", cmd.c_str());

    if (cmd == "FORWARD" || cmd == "BACK" || cmd == "LEFT" || cmd == "RIGHT") {
      gCmd = cmd;
      applyCmd();
      sendNotify(("OK " + cmd).c_str());
    } else if (cmd == "STOP") {
      gCmd = "STOP";
      driveMotors(0, 0);
      sendNotify("OK STOP");
    } else if (cmd.startsWith("SPEED:")) {
      int pct = cmd.substring(6).toInt();           // 0-100 %
      pct = constrain(pct, 0, 100);
      gSpeed = (int)(pct * 255L / 100);             // map to 0-255 for analogWrite
      applyCmd();                                   // 走行中なら即反映
      sendNotify(("OK SPEED:" + String(pct)).c_str());
    } else if (cmd == "STATUS") {
      int pct = (int)(gSpeed * 100L / 255);
      sendNotify(("STATUS cmd:" + gCmd + " speed:" + String(pct) + "%").c_str());
    } else {
      Serial.printf("Unknown command: %s\n", cmd.c_str());
      sendNotify("ERR UNKNOWN");
    }
  }
};

class ServerCallbacks : public BLEServerCallbacks {
  void onConnect(BLEServer* pServer) override {
    Serial.println("BLE connected");
  }
  void onDisconnect(BLEServer* pServer) override {
    Serial.println("BLE disconnected — restarting advertising");
    driveMotors(0, 0);  // 切断時はモーター停止
    BLEDevice::getAdvertising()->start();
  }
};

void setup() {
  pinMode(motorR_Pin1, OUTPUT);
  pinMode(motorR_Pin2, OUTPUT);
  pinMode(motorL_Pin1, OUTPUT);
  pinMode(motorL_Pin2, OUTPUT);
  pinMode(motorR_PWM, OUTPUT);
  pinMode(motorL_PWM, OUTPUT);

  driveMotors(0, 0);  // 起動時は停止

  Serial.begin(115200);

  // BLE初期化
  BLEDevice::init("mini_RC_OLED");

  BLEServer* pServer = BLEDevice::createServer();
  pServer->setCallbacks(new ServerCallbacks());

  BLEService* pService = pServer->createService(SERVICE_UUID);

  // RX: Python → ESP32 (書き込み)
  BLECharacteristic* pRxCharacteristic = pService->createCharacteristic(
    RX_UUID,
    BLECharacteristic::PROPERTY_WRITE
  );
  pRxCharacteristic->setCallbacks(new RxCallbacks());

  // TX: ESP32 → Python (通知)
  pTxCharacteristic = pService->createCharacteristic(
    TX_UUID,
    BLECharacteristic::PROPERTY_NOTIFY
  );
  pTxCharacteristic->addDescriptor(new BLE2902());

  pService->start();

  BLEAdvertising* pAdvertising = BLEDevice::getAdvertising();
  pAdvertising->addServiceUUID(SERVICE_UUID);
  pAdvertising->setScanResponse(true);
  pAdvertising->start();

  Serial.println("BLE started. Device: mini_RC_OLED");
}

void loop() {
  delay(10);
}